idl/SALOMEDS.idl

Go to the documentation of this file.

// Copyright (C) 2007-2011  CEA/DEN, EDF R&D, OPEN CASCADE
//
// Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
// CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
//
// This library is free software; you can redistribute it and/or
// modify it under the terms of the GNU Lesser General Public
// License as published by the Free Software Foundation; either
// version 2.1 of the License.
//
// This library is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
// Lesser General Public License for more details.
//
// You should have received a copy of the GNU Lesser General Public
// License along with this library; if not, write to the Free Software
// Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
//
// See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
//

//  File   : SALOMEDS.idl
//  Author : Yves FRICAUD
//
#ifndef _SALOMEDS_IDL_
#define _SALOMEDS_IDL_

#include "SALOME_Exception.idl"
#include "SALOME_GenericObj.idl"

module SALOMEDS
{
  typedef string URL;

  typedef string ID;

  typedef string PersistentReference;

  typedef string SalomeReference;

  typedef sequence<string> ListOfOpenStudies;
  typedef sequence<string> ListOfFileNames;
  typedef sequence<string> ListOfDates ;
  typedef sequence<string> ListOfStrings ;
  typedef sequence<ListOfStrings> ListOfListOfStrings ;
  typedef sequence<octet> TMPFile;

  // Reference to other objects is treated with function AddReference
  // and ReferencedObject
  // All other type of attributes defined in AttributeType enum are
  // treated with AddAdttribute and GetAttribute
  // The difference is made because Reference attribute don't contain
  // strings but reference to ID of other objects

  interface GenericAttribute;
  interface Study;
  interface StudyManager;
  interface StudyBuilder;
  interface SObject;
  interface SComponent;
  interface SComponentIterator;
  interface ChildIterator;
  interface Driver;
  interface AttributeStudyProperties;
  interface AttributeParameter;
  interface UseCaseIterator;
  interface UseCaseBuilder;

  interface Observer
  {
    oneway void notifyObserverID(in string theID, in long event);
  };


  typedef sequence<GenericAttribute> ListOfAttributes;

  exception NotImplemented {};


  //===========================================================================
  interface Study
  {

    exception StudyInvalidContext {};
    exception StudyInvalidComponent {};
    exception StudyInvalidDirectory {};
    exception StudyNameAlreadyUsed {};
    exception StudyObjectAlreadyExists {};
    exception StudyNameError {};
    exception StudyCommentError {};

    attribute string     Name; // equivalent to setName() & getName()
    attribute short      StudyId;
    typedef sequence<SObject> ListOfSObject;
    PersistentReference  GetPersistentReference();
    SalomeReference      GetTransientReference();

    boolean IsEmpty();
    SComponent FindComponent  (in string aComponentName);

    SComponent FindComponentID(in ID aComponentID);
    SObject       FindObject      (in string anObjectName);
    SObject       FindObjectID    (in ID aObjectID);
    SObject       CreateObjectID    (in ID aObjectID);
    SObject       FindObjectIOR   (in ID aObjectIOR);
    ListOfSObject FindObjectByName(in string anObjectName, in string aComponentName);
    SObject FindObjectByPath(in string thePath);
    string  GetObjectPath(in Object theObject);

    void SetContext(in string thePath);
    string GetContext();
    ListOfStrings GetObjectNames(in string theContext);
    ListOfStrings GetDirectoryNames(in string theContext);
    ListOfStrings GetFileNames(in string theContext);
    ListOfStrings GetComponentNames(in string theContext);
    ChildIterator      NewChildIterator(in SObject aSO);

    SComponentIterator NewComponentIterator();

    StudyBuilder NewBuilder() ;
    void UpdateIORLabelMap(in string anIOR, in string anEntry);

    AttributeStudyProperties GetProperties();
    attribute boolean IsSaved;
    boolean IsModified();

    void Modified();

    attribute string  URL;

    ListOfSObject FindDependances(in SObject anObject);

    string GetLastModificationDate();
    ListOfDates GetModificationsDate();
    string ConvertObjectToIOR(in Object theObject);
    Object ConvertIORToObject(in string theIOR);
    UseCaseBuilder  GetUseCaseBuilder();

    void Close();

    void EnableUseCaseAutoFilling(in boolean isEnabled);

    void AddPostponed(in string theIOR);

    void AddCreatedPostponed(in string theIOR);

    void RemovePostponed(in long theUndoLimit);

    void UndoPostponed(in long theWay);

    boolean DumpStudy(in string thePath,
                      in string theBaseName,
                      in boolean isPublished,
                      in boolean isMultiFile);

    AttributeParameter GetCommonParameters(in string theID, in long theSavePoint);

    AttributeParameter GetModuleParameters(in string theID, in string theModuleName, in long theSavePoint);


    string GetDefaultScript(in string theID, in string theModuleName);

    long long GetLocalImpl(in string theHostname, in long thePID, out boolean isLocal);


    void SetStudyLock(in string theLockerID);

    boolean IsStudyLocked();

    void UnLockStudy(in string theLockerID);

    ListOfStrings GetLockerID();

    void SetReal( in string theVarName, in double theValue );

    void SetInteger( in string theVarName, in long theValue );
    void SetBoolean( in string theVarName, in boolean theValue );

    void SetString( in string theVarName, in string theValue );

    void SetStringAsDouble( in string theVarName, in double theValue );

    double GetReal( in string theVarName );

    long GetInteger( in string theVarName );

    boolean GetBoolean( in string theVarName );

    string GetString( in string theVarName );
    

    boolean IsReal( in string theVarName );

    boolean IsInteger( in string theVarName );

    boolean IsBoolean( in string theVarName );

    boolean IsString( in string theVarName );

    boolean IsVariable( in string theVarName );

    ListOfStrings GetVariableNames();

    boolean RemoveVariable( in string theVarName );

    boolean RenameVariable( in string theVarName, in string theNewVarName );

    boolean IsVariableUsed( in string theVarName );

    ListOfListOfStrings ParseVariables( in string theVars );

     void attach(in SALOMEDS::Observer theObserver, in boolean modify);   
  };

  //==========================================================================
  //==========================================================================

  interface StudyBuilder
  {
    exception LockProtection {};
    SComponent NewComponent(in string ComponentDataType) raises(LockProtection);
    void       DefineComponentInstance (in SComponent aComponent,in Object ComponentIOR) raises(LockProtection);
        
    void       RemoveComponent(in SComponent aComponent) raises(LockProtection);

    SObject NewObject      (in SObject theFatherObject) raises(LockProtection);

    SObject NewObjectToTag (in SObject theFatherObject, in long atag) raises(LockProtection);
    void    RemoveObject   (in SObject anObject) raises(LockProtection);
    void    RemoveObjectWithChildren(in SObject anObject) raises(LockProtection);

    void  LoadWith (in SComponent sco, in Driver Engine) raises (SALOME::SALOME_Exception);
    void  Load (in SObject sco);

    GenericAttribute FindOrCreateAttribute(in  SObject        anObject,
                                      in  string         aTypeOfAttribute) raises(LockProtection);

    boolean FindAttribute(in  SObject        anObject,
                     out GenericAttribute anAttribute,
                     in  string         aTypeOfAttribute);
    void RemoveAttribute(in  SObject        anObject,
                in  string         aTypeOfAttribute) raises(LockProtection);
    void Addreference(in SObject anObject,
                in SObject theReferencedObject) ;

    void RemoveReference(in SObject anObject) ;

    void AddDirectory(in string theName) raises(LockProtection);

     void SetGUID(in SObject anObject, in string theGUID) raises(LockProtection);
     boolean IsGUID(in SObject anObject, in string theGUID);

    void NewCommand(); // command management
    void CommitCommand() raises(LockProtection); // command management
    boolean HasOpenCommand();
    void AbortCommand(); // command management
    attribute long  UndoLimit;
    void Undo() raises (LockProtection);
    void Redo() raises (LockProtection);
    boolean GetAvailableUndos();
    boolean GetAvailableRedos();
    void SetName(in SObject theSO, in string theValue) raises (LockProtection);

    void SetComment(in SObject theSO, in string theValue) raises (LockProtection);

    void SetIOR(in SObject theSO, in string theValue) raises (LockProtection);
  };

  //==========================================================================
  //==========================================================================

  interface StudyManager
  {
    void ping();

    void Shutdown();

    long getPID();

    oneway void ShutdownWithExit();

    Study NewStudy(in string study_name);

    Study Open (in URL aStudyUrl) raises (SALOME::SALOME_Exception);

    void  Close(in Study aStudy);
    boolean  Save(in  Study aStudy, in boolean theMultiFile);
    boolean  SaveASCII(in  Study aStudy, in boolean theMultiFile);
    boolean  SaveAs(in URL   aUrl, // if the file already exists
          in Study aStudy,
          in boolean theMultiFile); // overwrite (as option)
    boolean  SaveAsASCII(in URL   aUrl, // if the file already exists
                in Study aStudy,
                in boolean theMultiFile); // overwrite (as option)


    ListOfOpenStudies GetOpenStudies();

    Study GetStudyByName  (in string aStudyName);

    Study GetStudyByID  (in short aStudyID);

    // copy/paste methods

    boolean CanCopy(in SObject theObject);
    boolean Copy(in SObject theObject);
    boolean CanPaste(in SObject theObject);
    SObject Paste(in SObject theObject) raises (SALOMEDS::StudyBuilder::LockProtection);

    string ConvertObjectToIOR(in Object theObject);
    Object ConvertIORToObject(in string theIOR); 

    long long GetLocalImpl(in string theHostname, in long thePID, out boolean isLocal); 


  };


  //==========================================================================
  //==========================================================================

  interface SObject : SALOME::GenericObj
  {
    attribute string Name; // equivalent to setName() & getName()

    boolean IsNull();

    ID GetID();
    SComponent GetFatherComponent();
    SObject    GetFather();
    short      Tag();
    short      Depth();
    boolean FindSubObject (in long atag, out SObject obj);
    boolean FindAttribute(out GenericAttribute anAttribute,
                      in  string         aTypeOfAttribute);
    boolean ReferencedObject(out SObject obj); // A REVOIR
    ListOfAttributes     GetAllAttributes();
    Study GetStudy();

    Object GetObject();

    string GetName();

    string GetComment();

    string GetIOR();

    void SetAttrString(in string name, in string value);

    long long GetLocalImpl(in string theHostname, in long thePID, out boolean isLocal);
  };


  //==========================================================================
  //==========================================================================
  interface GenericAttribute : SALOME::GenericObj
  {
    exception LockProtection {};
    void CheckLocked() raises (LockProtection);

    string Type();

    string GetClassType();    
     
    SObject GetSObject();


    long long GetLocalImpl(in string theHostname, in long thePID, out boolean isLocal);
  };



  //==========================================================================
  //==========================================================================
  interface SComponent : SObject
  {
    string  ComponentDataType();
    boolean ComponentIOR (out ID theID); //returns True if there is an instance
                                         //In this case ID identifies this one
  };


  //==========================================================================
  //==========================================================================
  interface SComponentIterator : SALOME::GenericObj
  {
    void Init();
    boolean More();
    void Next();
    SComponent Value();
  };

  //==========================================================================
  //==========================================================================
  interface ChildIterator : SALOME::GenericObj
  {
    void Init();
    void InitEx(in boolean allLevels);
    boolean More();
    void Next();
    SObject Value();
  };

  //==========================================================================
  //==========================================================================
  interface UseCaseIterator : SALOME::GenericObj
  {
    void Init(in boolean allLevels);
    boolean More();
    void Next();
    SObject Value();
  };

  //==========================================================================
  //==========================================================================
  interface UseCaseBuilder : SALOME::GenericObj
  {
    boolean Append(in SObject theObject);
    boolean Remove(in SObject theObject);
    boolean AppendTo(in SObject theFather, in SObject theObject);
    boolean InsertBefore(in SObject theFirst, in SObject theNext);
    boolean SetCurrentObject(in SObject theObject);
    boolean SetRootCurrent();
    boolean HasChildren(in SObject theObject);
    boolean SetName(in string theName);
    string GetName();
    boolean IsUseCase(in SObject theObject);
    SObject GetCurrentObject();
    SObject AddUseCase(in string theName);
    UseCaseIterator GetUseCaseIterator(in SObject theObject);
  };
  //==========================================================================
  //==========================================================================
  interface Driver
  {

    TMPFile Save(in SComponent theComponent, in string theURL, in boolean isMultiFile);

    TMPFile SaveASCII(in SComponent theComponent, in string theURL, in boolean isMultiFile);

    boolean Load(in SComponent theComponent, in TMPFile theStream, in string theURL, in boolean isMultiFile);

    boolean LoadASCII(in SComponent theComponent, in TMPFile theStream, in string theURL, in boolean isMultiFile);

    void Close (in SComponent aSComponent);
    //void Close ( in string  aIORSComponent);

     string ComponentDataType();

    // Driver Transient -> persistent called for each object in study
    string IORToLocalPersistentID (in SObject theSObject,
                       in string IORString,
                       in boolean isMultiFile,
                       in boolean isASCII);
    string LocalPersistentIDToIOR (in SObject theSObject,
                       in string aLocalPersistentID,
                       in boolean isMultiFile,
                       in boolean isASCII)
      raises (SALOME::SALOME_Exception);

    // Publishing in the study
    boolean CanPublishInStudy(in Object theIOR) raises (SALOME::SALOME_Exception);
    SObject PublishInStudy(in Study theStudy, in SObject theSObject, in Object theObject, in string theName);

    // copy/paste methods

    boolean CanCopy(in SObject theObject);
    TMPFile CopyFrom(in SObject theObject, out long theObjectID);
    boolean CanPaste(in string theComponentName, in long theObjectID);
    SObject PasteInto(in TMPFile theStream, in long theObjectID, in SObject theObject);

  };
};

#endif