idl/SALOME_ContainerManager.idl

Go to the documentation of this file.

// Copyright (C) 2007-2011  CEA/DEN, EDF R&D, OPEN CASCADE
//
// Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
// CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
//
// This library is free software; you can redistribute it and/or
// modify it under the terms of the GNU Lesser General Public
// License as published by the Free Software Foundation; either
// version 2.1 of the License.
//
// This library is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
// Lesser General Public License for more details.
//
// You should have received a copy of the GNU Lesser General Public
// License along with this library; if not, write to the Free Software
// Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
//
// See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
//

#ifndef _SALOME_CONTAINERMANAGER_IDL_
#define _SALOME_CONTAINERMANAGER_IDL_

#include "SALOME_Exception.idl"
#include "SALOME_Component.idl"

module Engines
{

typedef sequence<string> ResourceList;
typedef sequence<string> CompoList;
typedef sequence<string> FilesList;
typedef sequence<string> ModulesList;

struct Parameter
{
  string name;
  string value;
};
typedef sequence<Engines::Parameter> ParameterList;

struct ResourceParameters
{
  string name;
  string hostname;
  string OS;
  CompoList componentList;

  // Permits to order resources
  long nb_proc;
  long mem_mb;
  long cpu_clock;
  long nb_node;
  long nb_proc_per_node;

  // Permits to configure SALOME resource management
  string policy;
  ResourceList resList;
};

struct ContainerParameters
{
  string container_name;


  string mode;

  string workingdir;

  // Parallel part
  long nb_proc;
  boolean isMPI;
  string parallelLib;

  ResourceParameters resource_params;
};

struct ResourceDefinition
{
  string name;
  string hostname;
  string protocol;
  string username;
  string applipath;
  CompoList componentList;
  string mode;

  string OS;
  long mem_mb;
  long cpu_clock;
  long nb_node;
  long nb_proc_per_node;
  string batch;
  string mpiImpl;
  string iprotocol;
};

exception NotFound {};

struct JobParameters
{
  string job_name;
  string job_type;

  // Common values
  string job_file;
  string env_file; 
  FilesList in_files;
  FilesList out_files;
  string work_directory;
  string local_directory;
  string result_directory;

  string maximum_duration; 

  // Memory is expressed in megabytes -> mem_mb
  // Number of Processors -> nb_proc
  ResourceParameters resource_required;

  string queue;

  Engines::ParameterList specific_parameters;
};

struct JobDescription
{
  long job_id;
  Engines::JobParameters job_parameters;
};
typedef sequence<Engines::JobDescription> JobsList;

interface SalomeLauncherObserver
{
  void notify(in string event_name, in string event_data);
};

interface SalomeLauncher
{
  // Main methods
  long   createJob    (in Engines::JobParameters job_parameters) raises (SALOME::SALOME_Exception);
  void   launchJob    (in long job_id)                           raises (SALOME::SALOME_Exception);
  string getJobState  (in long job_id)                           raises (SALOME::SALOME_Exception);
  void   getJobResults(in long job_id, in string directory)      raises (SALOME::SALOME_Exception);
  boolean getJobDumpState(in long job_id, in string directory)   raises (SALOME::SALOME_Exception);
  void   removeJob    (in long job_id)                           raises (SALOME::SALOME_Exception);

  // Useful methods
  long    createJobWithFile(in string xmlJobFile, in string clusterName) raises (SALOME::SALOME_Exception);
  boolean testBatch        (in ResourceParameters params)                raises (SALOME::SALOME_Exception);

  // SALOME kernel service methods
  void Shutdown();
  long getPID();

  // Observer and introspection methods
  void addObserver(in Engines::SalomeLauncherObserver observer);
  void removeObserver(in Engines::SalomeLauncherObserver observer);
  Engines::JobsList getJobsList();
  Engines::JobParameters getJobParameters(in long job_id) raises (SALOME::SALOME_Exception);

  // Save and load methods
  void loadJobs(in string jobs_file) raises (SALOME::SALOME_Exception);
  void saveJobs(in string jobs_file) raises (SALOME::SALOME_Exception);

};
  
interface ContainerManager
{
  Container GiveContainer(in ContainerParameters params) raises (SALOME::SALOME_Exception);

  void ShutdownContainers();
} ;
  
interface ResourcesManager
{
  string FindFirst(in ResourceList possibleResources);

  string Find(in string policy, in ResourceList possibleResources);


  ResourceList GetFittingResources(in ResourceParameters params) raises (SALOME::SALOME_Exception);

  ResourceDefinition GetResourceDefinition(in string name);


  void AddResource(in ResourceDefinition new_resource, in boolean write, in string xml_file) 
    raises (SALOME::SALOME_Exception);


  void RemoveResource(in string resource_name, in boolean write, in string xml_file) 
    raises (SALOME::SALOME_Exception);
};


// For compatibility - will be erased on SALOME 6
typedef sequence<string> MachineList;
struct MachineParameters
{
  string container_name;
  string hostname;
  CompoList componentList;
  MachineList computerList;
  string OS;
  long mem_mb;
  long cpu_clock;
  long nb_proc_per_node;
  long nb_node;
  boolean isMPI;
  string workingdir;

  string mode;
  string policy;

  string parallelLib;
  long nb_component_nodes;
};
};
  
#endif