idl/MED.idl

Go to the documentation of this file.

// Copyright (C) 2007-2011  CEA/DEN, EDF R&D, OPEN CASCADE
//
// Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
// CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
//
// This library is free software; you can redistribute it and/or
// modify it under the terms of the GNU Lesser General Public
// License as published by the Free Software Foundation; either
// version 2.1 of the License.
//
// This library is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
// Lesser General Public License for more details.
//
// You should have received a copy of the GNU Lesser General Public
// License along with this library; if not, write to the Free Software
// Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
//
// See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
//

// File: MED.idl
// Project: SALOME
//
#ifndef MED_IDL
#define MED_IDL

#include "SALOME_GenericObj.idl"
#include "SALOME_Exception.idl"
#include "SALOME_Component.idl"
#include "SALOME_Types.idl"
#include "SALOMEDS.idl"
#include "SALOME_Comm.idl"

module SALOME_MED
{
  interface FIELD;
  interface FAMILY;
  interface GROUP;
  interface GMESH;
  interface MESH;
  interface SUPPORT;

  typedef long medGeometryElement;
  const medGeometryElement MED_NONE = 0;
  const medGeometryElement MED_POINT1 = 1;
  const medGeometryElement MED_SEG2 = 102;
  const medGeometryElement MED_SEG3 = 103;
  const medGeometryElement MED_TRIA3 = 203;
  const medGeometryElement MED_QUAD4 = 204;
  const medGeometryElement MED_TRIA6 = 206;
  const medGeometryElement MED_QUAD8 = 208;
  const medGeometryElement MED_TETRA4 = 304;
  const medGeometryElement MED_PYRA5 = 305;
  const medGeometryElement MED_PENTA6 = 306;
  const medGeometryElement MED_HEXA8 = 308;
  const medGeometryElement MED_TETRA10 = 310;
  const medGeometryElement MED_PYRA13 = 313;
  const medGeometryElement MED_PENTA15 = 315;
  const medGeometryElement MED_HEXA20 = 320;
  const medGeometryElement MED_POLYGON = 400;
  const medGeometryElement MED_POLYHEDRA = 500;
  const medGeometryElement MED_ALL_ELEMENTS = 999;


  typedef long medEntityMesh;
  const medEntityMesh MED_CELL = 0;
  const medEntityMesh MED_FACE = 1;
  const medEntityMesh MED_EDGE = 2;
  const medEntityMesh MED_NODE = 3;
  const medEntityMesh MED_ALL_ENTITIES = 4;

  typedef long medModeSwitch;
  const medModeSwitch MED_FULL_INTERLACE = 0;
  const medModeSwitch MED_NO_INTERLACE = 1;
  const medModeSwitch MED_NO_INTERLACE_BY_TYPE = 2;

  typedef long medConnectivity;
  const medConnectivity MED_NODAL = 0;
  const medConnectivity MED_DESCENDING = 1;


    typedef long medDriverTypes;
    const medDriverTypes MED_DRIVER  = 0;
    const medDriverTypes VTK_DRIVER = 1;
    const medDriverTypes NO_DRIVER = 2;

  typedef sequence<medGeometryElement> medGeometryElement_array;

  typedef sequence<FAMILY> Family_array;

  typedef sequence<GROUP> Group_array;

  // ----------------------
  // base mesh interface
  // ----------------------

  interface GMESH : SALOME::MultiCommClass, SALOME::GenericObj 
  {
    // Index range begins from 1

    // General Informations
    //---------------------

    string getName() raises (SALOME::SALOME_Exception);

    long getSpaceDimension() raises (SALOME::SALOME_Exception);

    long getMeshDimension() raises (SALOME::SALOME_Exception);

    boolean getIsAGrid() raises (SALOME::SALOME_Exception);

    string getCoordinatesSystem() raises (SALOME::SALOME_Exception);

    long getNumberOfNodes() raises (SALOME::SALOME_Exception);

    SALOME_TYPES::ListOfString getCoordinatesNames()
      raises (SALOME::SALOME_Exception);

    SALOME_TYPES::ListOfString getCoordinatesUnits()
      raises (SALOME::SALOME_Exception);

    SUPPORT getBoundaryElements(in medEntityMesh Entity)
      raises (SALOME::SALOME_Exception);

    SUPPORT getSupportOnAll(in medEntityMesh Entity)
      raises (SALOME::SALOME_Exception);

    SUPPORT getSkin(in SUPPORT mySupport3D ) raises (SALOME::SALOME_Exception);

    struct coordinateInfos
    {
     string               coordSystem;
     SALOME_TYPES::ListOfString coordNames;
     SALOME_TYPES::ListOfString coordUnits;
    };
    coordinateInfos getCoordGlobal()    raises (SALOME::SALOME_Exception);



    // Connectivity
    // ------------

    long getNumberOfTypes(in medEntityMesh entity)
      raises (SALOME::SALOME_Exception);

    medGeometryElement_array getTypes(in medEntityMesh entity)
      raises (SALOME::SALOME_Exception);

    long getNumberOfElements(in medEntityMesh entity,
                    in medGeometryElement geomElement)
      raises (SALOME::SALOME_Exception);

    medGeometryElement   getElementType (in  medEntityMesh entity,
                           in long number)
      raises (SALOME::SALOME_Exception);

    // Families and Groups
    // -------------------

    long getNumberOfFamilies(in medEntityMesh entity)
      raises (SALOME::SALOME_Exception);

    long getNumberOfGroups(in medEntityMesh entity)
      raises (SALOME::SALOME_Exception);

    Family_array getFamilies(in medEntityMesh entity)
      raises (SALOME::SALOME_Exception);

    FAMILY getFamily(in medEntityMesh entity,in long familyNumber)
      raises (SALOME::SALOME_Exception);

    Group_array getGroups(in medEntityMesh entity)
      raises (SALOME::SALOME_Exception);

    GROUP getGroup(in medEntityMesh entity,in long groupNumber)
      raises (SALOME::SALOME_Exception);

    // Others
    // ------

    FIELD getVolume(in SUPPORT mySupport)
      raises (SALOME::SALOME_Exception);

    FIELD getArea(in SUPPORT mySupport)
      raises (SALOME::SALOME_Exception);

    FIELD getLength(in SUPPORT mySupport)
      raises (SALOME::SALOME_Exception);

    FIELD getNormal(in SUPPORT mySupport)
      raises (SALOME::SALOME_Exception);

    FIELD getBarycenter(in SUPPORT mySupport)
      raises (SALOME::SALOME_Exception);

    /*
      Returns a field on mySupport containing neighbourhood.
    */
    // FIELD getNeighbourhood(in SUPPORT mySupport)
    // raises (SALOME::SALOME_Exception);

    // Read & Write
    // -----------

    void addInStudy(in SALOMEDS::Study myStudy, in GMESH myIor )
      raises (SALOME::SALOME_Exception, SALOMEDS::StudyBuilder::LockProtection);

    //                         Add a MED/VTK/... driver
    //                          Multiple drivers can be added whatever the type
    long addDriver     (in medDriverTypes driverType, in string  fileName, in string meshName)
                                        raises (SALOME::SALOME_Exception);
    //                          Remove a driver
    void rmDriver      (in long i)  raises (SALOME::SALOME_Exception);

   //
    void read          (in long i)  raises (SALOME::SALOME_Exception);
    void write         (in long i, in string driverMeshName)
                                    raises (SALOME::SALOME_Exception);

    long getCorbaIndex()      raises (SALOME::SALOME_Exception);
    struct meshInfos
    {
           string name ;
           long spaceDimension ;
        long meshDimension;
        long numberOfNodes ;
           boolean isAGrid;
           Family_array famNode;
           Family_array famEdge;
           Family_array famFace;
           Family_array famCell;
        Group_array  groupNode;
        Group_array  groupEdge;
        Group_array  groupFace;
        Group_array  groupCell;
    };
    meshInfos getMeshGlobal()      raises (SALOME::SALOME_Exception);
    boolean areEquals(in GMESH other);

    MESH convertInMESH();
  };

  // ----------------------
  // mesh interface
  // ----------------------

  interface MESH : GMESH {

    boolean existConnectivity (in medConnectivity mode,
                      in medEntityMesh entity)
                      raises (SALOME::SALOME_Exception);

    // Coordinates
    //------------

    SALOME_TYPES::ListOfDouble getCoordinates(in medModeSwitch typeSwitch)
      raises (SALOME::SALOME_Exception);

    SALOME::SenderDouble getSenderForCoordinates(in medModeSwitch typeSwitch)
      raises (SALOME::SALOME_Exception);
    double getCoordinate(in long Number, in long Axis)
      raises (SALOME::SALOME_Exception);

    SALOME_TYPES::ListOfLong getGlobalNumberingIndex(in medEntityMesh entity) ;


    // Connectivity
    // ------------

    SALOME_TYPES::ListOfLong getConnectivity(in medConnectivity mode,
                                           in medEntityMesh entity,
                                           in medGeometryElement geomElement)
      raises (SALOME::SALOME_Exception);

    SALOME::SenderInt getSenderForConnectivity(in medConnectivity mode,
                                               in medEntityMesh entity,
                                               in medGeometryElement geomElement)
      raises (SALOME::SALOME_Exception);

    SALOME_TYPES::ListOfLong getConnectivityIndex(in medConnectivity mode,
                                                in medEntityMesh entity)
      raises (SALOME::SALOME_Exception);

    SALOME::SenderInt getSenderForConnectivityIndex(in medConnectivity mode,
                                                    in medEntityMesh entity,
                                                    in medGeometryElement geomElement)
      raises (SALOME::SALOME_Exception);

    long getElementNumber(in medConnectivity mode,
                 in medEntityMesh entity,
                 in medGeometryElement type,
                 in SALOME_TYPES::ListOfLong connectivity)
      raises (SALOME::SALOME_Exception);

    SALOME_TYPES::ListOfLong getReverseConnectivity(in medConnectivity mode)
      raises (SALOME::SALOME_Exception);

    SALOME_TYPES::ListOfLong getReverseConnectivityIndex(in medConnectivity mode)
      raises (SALOME::SALOME_Exception);

    struct connectivityInfos
    {
     long                     numberOfNodes;
        medGeometryElement_array meshTypes;
     SALOME_TYPES::ListOfLong   numberOfElements;
     SALOME_TYPES::ListOfLong   nodalConnectivityLength;
        long                     entityDimension;
    };
    connectivityInfos getConnectGlobal(in medEntityMesh entity)
    raises (SALOME::SALOME_Exception);

  };


  // ----------------------
  // Support interface
  // ----------------------

  interface SUPPORT : SALOME::MultiCommClass, SALOME::GenericObj {

    string getName() raises (SALOME::SALOME_Exception);

    string getDescription() raises (SALOME::SALOME_Exception);

    GMESH getMesh() raises (SALOME::SALOME_Exception);

    medEntityMesh getEntity() raises (SALOME::SALOME_Exception);

    boolean isOnAllElements() raises (SALOME::SALOME_Exception);

    long getNumberOfElements(in medGeometryElement geomElement)
      raises (SALOME::SALOME_Exception);

     long  getNumberOfTypes() raises (SALOME::SALOME_Exception);
    medGeometryElement_array getTypes() raises (SALOME::SALOME_Exception);


    SALOME_TYPES::ListOfLong getNumber(in medGeometryElement geomElement)
      raises (SALOME::SALOME_Exception);

    SALOME_TYPES::ListOfLong getNumberFromFile(in medGeometryElement geomElement)
      raises (SALOME::SALOME_Exception);

    SALOME::SenderInt getSenderForNumber(in medGeometryElement geomElement)
      raises (SALOME::SALOME_Exception);

    SALOME_TYPES::ListOfLong getNumberIndex()
      raises (SALOME::SALOME_Exception);

    SALOME::SenderInt getSenderForNumberIndex()
      raises (SALOME::SALOME_Exception);

    void getBoundaryElements()
                              raises (SALOME::SALOME_Exception);
    long getCorbaIndex()              raises (SALOME::SALOME_Exception);
    struct supportInfos
    {
           string    name;
        string       description;
        boolean       isOnAllElements;
        medEntityMesh entity;
           long          numberOfGeometricType;
           medGeometryElement_array types;
           SALOME_TYPES::ListOfLong   nbEltTypes;
           SALOME_TYPES::ListOfLong   nodalConnectivityLength;
    };
    supportInfos getSupportGlobal()          raises (SALOME::SALOME_Exception);

  };


  //-----------------
  // Family interface
  //-----------------

  interface FAMILY : SUPPORT
    {

      long getIdentifier() raises (SALOME::SALOME_Exception);

      long getNumberOfAttributes() raises (SALOME::SALOME_Exception);

      SALOME_TYPES::ListOfLong getAttributesIdentifiers()
     raises (SALOME::SALOME_Exception);

      long getAttributeIdentifier(in long i) raises (SALOME::SALOME_Exception);

      SALOME_TYPES::ListOfLong getAttributesValues()
     raises (SALOME::SALOME_Exception);

      long getAttributeValue(in long i) raises (SALOME::SALOME_Exception);

      SALOME_TYPES::ListOfString getAttributesDescriptions()
     raises (SALOME::SALOME_Exception);

      string getAttributeDescription(in long i)
     raises (SALOME::SALOME_Exception);

      long getNumberOfGroups()
     raises (SALOME::SALOME_Exception);

      SALOME_TYPES::ListOfString getGroupsNames()
     raises (SALOME::SALOME_Exception);

      string getGroupName(in long i)
     raises (SALOME::SALOME_Exception);


    };


  //----------------
  // Group interface
  //----------------
  interface GROUP : SUPPORT
    {

      long getNumberOfFamilies() raises (SALOME::SALOME_Exception);

      Family_array getFamilies() raises (SALOME::SALOME_Exception);

      FAMILY getFamily(in long i) raises (SALOME::SALOME_Exception);

    };


  //----------------
  // Field interface
  //----------------

  interface FIELD : SALOME::GenericObj
    {

      string getName() raises (SALOME::SALOME_Exception);

      void setName (in string theName) raises (SALOME::SALOME_Exception);

      string getDescription() raises (SALOME::SALOME_Exception);

      SUPPORT getSupport() raises (SALOME::SALOME_Exception);

      long getNumberOfComponents() raises (SALOME::SALOME_Exception);

      SALOME_TYPES::ListOfString getComponentsNames()
     raises (SALOME::SALOME_Exception);

      string getComponentName(in long i) raises (SALOME::SALOME_Exception);

      SALOME_TYPES::ListOfString getComponentsUnits()
     raises (SALOME::SALOME_Exception);

      string getComponentUnit(in long i) raises (SALOME::SALOME_Exception);

      SALOME_TYPES::ListOfString getComponentsDescriptions()
     raises (SALOME::SALOME_Exception);

      string getComponentDescription(in long i) raises (SALOME::SALOME_Exception);

      long getIterationNumber() raises (SALOME::SALOME_Exception);

      double getTime() raises (SALOME::SALOME_Exception);

      long getOrderNumber() raises (SALOME::SALOME_Exception);

      boolean getGaussPresence();

      // Read & Write
      // -----------

      long addDriver (in medDriverTypes driverType, in string  fileName, in string fieldName)
     raises (SALOME::SALOME_Exception);

      void rmDriver (in long i)
     raises (SALOME::SALOME_Exception);

      //
      void read (in long i)
     raises (SALOME::SALOME_Exception);

      void write (in long i, in string driverFieldName)
     raises (SALOME::SALOME_Exception);

      void addInStudy(in SALOMEDS::Study myStudy, in FIELD myIor)
     raises (SALOME::SALOME_Exception, SALOMEDS::StudyBuilder::LockProtection);
      void addInStudyToComponent(in SALOMEDS::SComponent myComponent, in FIELD myIor)
     raises (SALOME::SALOME_Exception, SALOMEDS::StudyBuilder::LockProtection);

      long getCorbaIndex()
     raises (SALOME::SALOME_Exception);

    };


  interface FIELDDOUBLE : FIELD , SALOME::MultiCommClass {

    SALOME_TYPES::ListOfDouble getValue(in medModeSwitch mode)
      raises (SALOME::SALOME_Exception);

    SALOME::SenderDouble getSenderForValue(in medModeSwitch mode)
      raises (SALOME::SALOME_Exception);
  };

  interface FIELDDOUBLENO : FIELDDOUBLE {
  };

  interface FIELDDOUBLENOBYTYPE : FIELDDOUBLE {
  };

  interface FIELDDOUBLEFULL : FIELDDOUBLE {
  };

  interface FIELDINT : FIELD , SALOME::MultiCommClass {

    SALOME_TYPES::ListOfLong getValue(in medModeSwitch mode)
      raises (SALOME::SALOME_Exception);

    SALOME::SenderInt getSenderForValue(in medModeSwitch mode)
      raises (SALOME::SALOME_Exception);
  };

  interface FIELDINTNO : FIELDINT {
  };

  interface FIELDINTNOBYTYPE : FIELDINT {
  };

  interface FIELDINTFULL : FIELDINT {
  };

  // MED interface

  interface MED : SALOME::GenericObj {
    long                   getNumberOfMeshes () raises (SALOME::SALOME_Exception);
    long                   getNumberOfFields () raises (SALOME::SALOME_Exception);
    SALOME_TYPES::ListOfString  getMeshNames      () raises (SALOME::SALOME_Exception);
    SALOME_TYPES::ListOfString  getFieldNames     () raises (SALOME::SALOME_Exception);
    GMESH                   getMeshByName     ( in string  meshName)  raises (SALOME::SALOME_Exception);
    GMESH                   getMesh           ( in FIELD  fieldPtr)   raises (SALOME::SALOME_Exception);
    long getFieldNumberOfIteration(in string fieldName) raises (SALOME::SALOME_Exception);
    SALOME_TYPES::ListOfLong  getFieldIteration(in string fieldName, in long i) raises (SALOME::SALOME_Exception);
    SALOME_TYPES::ListOfLong  getFieldIterations(in string fieldName) raises (SALOME::SALOME_Exception);
    FIELD                  getField          ( in string fieldName,
                                in long pasTemps,
                                in long numOrdre )    raises (SALOME::SALOME_Exception);


    // Add a MED/VTK/... driver to a MED'GEN' object to
    // be able to read/write files preserving  meshes<-->fields association
    // Multiple drivers can be added whatever the type.
    // The access point in the <long> returned
    long addDriver     (in medDriverTypes driverType, in string  fileName)
                                        raises (SALOME::SALOME_Exception);
    void rmDriver      (in long i)  raises (SALOME::SALOME_Exception);
    void readFileStruct(in long i)  raises (SALOME::SALOME_Exception);
    void writeFrom     (in long i)  raises (SALOME::SALOME_Exception);
    void write         (in long i)  raises (SALOME::SALOME_Exception);

    void addMesh  (in GMESH  ptrMesh   ) raises (SALOME::SALOME_Exception);
    void addField (in FIELD  ptrField  ) raises (SALOME::SALOME_Exception);

    void addInStudy (in SALOMEDS::Study myStudy, in MED medPtr) raises (SALOME::SALOME_Exception, SALOMEDS::StudyBuilder::LockProtection);
  };
  
  struct MedFileInfo
  {
    string fileName; 
    long   fileSize; 
    long   major, minor, release; 
  };
};

#endif /* MED_IDL */