idl/SMESH_Gen.idl

Go to the documentation of this file.

// Copyright (C) 2007-2011  CEA/DEN, EDF R&D, OPEN CASCADE
//
// Copyright (C) 2003-2007  OPEN CASCADE, EADS/CCR, LIP6, CEA/DEN,
// CEDRAT, EDF R&D, LEG, PRINCIPIA R&D, BUREAU VERITAS
//
// This library is free software; you can redistribute it and/or
// modify it under the terms of the GNU Lesser General Public
// License as published by the Free Software Foundation; either
// version 2.1 of the License.
//
// This library is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
// Lesser General Public License for more details.
//
// You should have received a copy of the GNU Lesser General Public
// License along with this library; if not, write to the Free Software
// Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307 USA
//
// See http://www.salome-platform.org/ or email : webmaster.salome@opencascade.com
//
//  File   : SMESH_Gen.idl
//  Author : Paul RASCLE, EDF

#ifndef _SMESH_GEN_IDL_
#define _SMESH_GEN_IDL_

#include "SALOME_Exception.idl"
#include "SALOME_Component.idl"
#include "SALOMEDS.idl"

#include "GEOM_Gen.idl"

#include "SMESH_Mesh.idl"
#include "SMESH_Hypothesis.idl"

module SMESH
{
  typedef sequence<GEOM::GEOM_Object> object_array;
  typedef sequence<SMESH_Mesh>        mesh_array;

  interface FilterManager;
  interface SMESH_Pattern;
  interface Measurements;

  // Top level
  const long Tag_HypothesisRoot = 1; // hypotheses root
  const long Tag_AlgorithmsRoot = 2; // algorithms root
  const long Tag_FirstMeshRoot  = 3; // first mesh root
  // Mesh/Submesh
  const long Tag_RefOnShape             = 1; // references to shape
  const long Tag_RefOnAppliedHypothesis = 2; // applied hypotheses root
  const long Tag_RefOnAppliedAlgorithms = 3; // applied algorithms root
  // Mesh only: sub-meshes roots by type
  const long Tag_FirstSubMesh           =  4;
  const long Tag_SubMeshOnVertex        =  4;
  const long Tag_SubMeshOnEdge          =  5;
  const long Tag_SubMeshOnWire          =  6;
  const long Tag_SubMeshOnFace          =  7;
  const long Tag_SubMeshOnShell         =  8;
  const long Tag_SubMeshOnSolid         =  9;
  const long Tag_SubMeshOnCompound      = 10;
  const long Tag_LastSubMesh            = 10;
  // Mesh only: group roots by type
  const long Tag_FirstGroup             = 11;
  const long Tag_NodeGroups             = 11;
  const long Tag_EdgeGroups             = 12;
  const long Tag_FaceGroups             = 13;
  const long Tag_VolumeGroups           = 14;
  const long Tag_0DElementsGroups       = 15;
  const long Tag_LastGroup              = 15;

  struct AlgoStateError
  {
    Hypothesis_Status  state;
    string             algoName;
    long               algoDim;
    boolean            isGlobalAlgo;
  };
  typedef sequence<AlgoStateError> algo_error_array;

  enum ComputeErrorName
  {
    COMPERR_OK            ,
    COMPERR_BAD_INPUT_MESH,  // wrong mesh on lower submesh
    COMPERR_STD_EXCEPTION ,  // some std exception raised
    COMPERR_OCC_EXCEPTION ,  // OCC exception raised
    COMPERR_SLM_EXCEPTION ,  // SALOME exception raised
    COMPERR_EXCEPTION     ,  // other exception raised
    COMPERR_MEMORY_PB     ,  // memory allocation problem
    COMPERR_ALGO_FAILED   ,  // computation failed
    COMPERR_BAD_SHAPE        // bad geometry
  };
  struct ComputeError
  {
    short   code;       // ComputeErrorName or, if negative, algo specific code
    string  comment;    // textual problem description
    string  algoName;
    short   subShapeID; // id of subshape of a shape to mesh
    boolean hasBadMesh; // there are elements preventing computation available for visualization
  };
  typedef sequence<ComputeError> compute_error_array;


  interface SMESH_Gen : Engines::EngineComponent, SALOMEDS::Driver
  {
    //GEOM::GEOM_Gen SetGeomEngine( in string containerLoc );
    void SetGeomEngine( in GEOM::GEOM_Gen geomcompo );

    FilterManager CreateFilterManager();

    SMESH_Pattern GetPattern();

    Measurements  CreateMeasurements();

    void SetEmbeddedMode( in boolean theMode );

    boolean IsEmbeddedMode();

    void SetCurrentStudy( in SALOMEDS::Study theStudy );

    SALOMEDS::Study GetCurrentStudy();

    SMESH_Hypothesis CreateHypothesis( in string theHypName,
                                       in string theLibName )
      raises ( SALOME::SALOME_Exception );

    SMESH_Hypothesis GetHypothesisParameterValues( in string            theHypName,
                                                   in string            theLibName,
                                                   in SMESH_Mesh        theMesh,
                                                   in GEOM::GEOM_Object theGeom,
                                                   in boolean           byMesh)
      raises ( SALOME::SALOME_Exception );

    void SetBoundaryBoxSegmentation( in long theNbSegments ) raises ( SALOME::SALOME_Exception );
    void SetDefaultNbSegments( in long theNbSegments) raises ( SALOME::SALOME_Exception );

    void SetName( in string theObjectIOR,
                  in string theObjectName )
      raises ( SALOME::SALOME_Exception );

    SMESH_Mesh CreateMesh( in GEOM::GEOM_Object theObject )
      raises ( SALOME::SALOME_Exception );

    SMESH_Mesh CreateEmptyMesh()
      raises ( SALOME::SALOME_Exception );

    SMESH_Mesh CreateMeshesFromUNV( in string theFileName )
      raises ( SALOME::SALOME_Exception );

     mesh_array CreateMeshesFromMED( in string theFileName,
                                     out SMESH::DriverMED_ReadStatus theStatus )
       raises ( SALOME::SALOME_Exception );

    SMESH_Mesh CreateMeshesFromSTL( in string theFileName )
      raises ( SALOME::SALOME_Exception );

    SMESH_Mesh CopyMesh(in SMESH_IDSource meshPart,
                        in string         meshName,
                        in boolean        toCopyGroups,
                        in boolean        toKeepIDs)
      raises ( SALOME::SALOME_Exception );

    SMESH_Mesh Concatenate(in mesh_array theMeshesArray,
                           in boolean    theUniteIdenticalGroups,
                           in boolean    theMergeNodesAndElements,
                           in double     theMergeTolerance)
      raises ( SALOME::SALOME_Exception );

    SMESH_Mesh ConcatenateWithGroups(in mesh_array theMeshesArray,
                                     in boolean    theUniteIdenticalGroups,
                                     in boolean    theMergeNodesAndElements,
                                     in double     theMergeTolerance)
      raises ( SALOME::SALOME_Exception );

    boolean Compute( in SMESH_Mesh        theMesh,
                     in GEOM::GEOM_Object theSubObject )
      raises ( SALOME::SALOME_Exception );

    void CancelCompute( in SMESH_Mesh        theMesh,
               in GEOM::GEOM_Object theSubObject );

    boolean IsReadyToCompute( in SMESH_Mesh        theMesh,
                              in GEOM::GEOM_Object theSubObject )
      raises ( SALOME::SALOME_Exception );

    long_array  Evaluate(in SMESH_Mesh        theMesh,
                         in GEOM::GEOM_Object theSubObject)
      raises ( SALOME::SALOME_Exception );

    MeshPreviewStruct Precompute( in SMESH_Mesh        theMesh,
                                  in GEOM::GEOM_Object theSubObject,
                                  in Dimension         theDimension,
                                  inout long_array    theShapesId )
      raises ( SALOME::SALOME_Exception );

    algo_error_array GetAlgoState( in SMESH_Mesh        theMesh,
                                   in GEOM::GEOM_Object theSubObject )
      raises ( SALOME::SALOME_Exception );

    compute_error_array GetComputeErrors( in SMESH_Mesh        theMesh,
                                          in GEOM::GEOM_Object theSubObject )
      raises ( SALOME::SALOME_Exception );

    MeshPreviewStruct GetBadInputElements( in SMESH_Mesh theMesh,
                                           in short      theSubShapeID )
      raises ( SALOME::SALOME_Exception );

    long_array GetSubShapesId( in GEOM::GEOM_Object theMainObject,
                               in object_array      theListOfSubObjects )
       raises ( SALOME::SALOME_Exception );

    GEOM::GEOM_Object GetGeometryByMeshElement( in SMESH_Mesh  theMesh,
                                                in long        theElementID,
                                                in string      theGeomName)
      raises ( SALOME::SALOME_Exception );

    GEOM::GEOM_Object FindGeometryByMeshElement( in SMESH_Mesh  theMesh,
                                                 in long        theElementID)
      raises ( SALOME::SALOME_Exception );

    long GetObjectId(in Object theObject);

    boolean GetMEDVersion(in string theFileName, out MED_VERSION theVersion);

    string_array GetMeshNames(in string theFileName);
  };

};

#endif